procedure TForm1.EngineBeforeDeleteTrigger(Sender: TObject;
  TriggerSession: TDBISAMSession; TriggerDatabase: TDBISAMDatabase;
  const TableName: String; CurrentRecord: TDBISAMRecord);
var
   OrdersQuery: TDBISAMQuery;
begin
   if (AnsiCompareText(TableName,'customer')=0) then
      begin
      TriggerDatabase.StartTransaction;
      OrdersQuery:=TDBISAMQuery.Create(nil);
      try
         with OrdersQuery do
            begin
            SessionName:=TriggerDatabase.SessionName;
            DatabaseName:=TriggerDatabase.DatabaseName;
            RequestLive:=True;
            SQL.Text:='DELETE FROM Orders '+
                      'WHERE CustNo=:CustNo';
            ParamByName('CustNo').AsFloat:=CurrentRecord.FieldByName('CustNo').AsFloat;
            ExecSQL;
            end;
      finally
         OrdersQuery.Free;
      end;
      end;
end;

procedure TForm1.EngineDeleteError(Sender: TObject;
  ErrorSession: TDBISAMSession; ErrorDatabase: TDBISAMDatabase;
  const TableName: String; CurrentRecord: TDBISAMRecord; E: Exception;
  var Action: TDataAction);
begin
   Action:=daFail;
   if ErrorDatabase.InTransaction then
      ErrorDatabase.Rollback;
end;

procedure TForm1.EngineAfterDeleteTrigger(Sender: TObject;
  TriggerSession: TDBISAMSession; TriggerDatabase: TDBISAMDatabase;
  const TableName: String; CurrentRecord: TDBISAMRecord);
begin
   if (AnsiCompareText(TableName,'customer')=0) then
      begin
      if TriggerDatabase.InTransaction then
         TriggerDatabase.Commit;
      end;
end;